Palace Planet :: One Planet One Palace

Welcome Guest

HOME

DIRECTORY

LINKS

FILES

GALLERY

FORUM

SCRIPTS

MANUALS

Main Menu
Home
Member List
Lost Password
Links
Glossary
Directory

User Input!
Submit Link
Submit Article

Quick Downloads
PC Client software
PC Client Upgrader
MAC Client Software
MAC Client fix
PC Server

Online Manuals
Newcomers Guide
Client Manual
Server Manual
Iptscrae Manual
FAQ
Kids Online safety
Netiquette
Admin

Events
articles: 45
SuperSCoop
articles: 5
The Planet
articles: 6
56 articles.
9947 times read

no members online:)

To LOGIN or REGISTER
click here

Script Details

Scripts Name : Wiz Scripts 2

Type of Script : Cyborg Scripts

Installation Procedures:

Shortcut scripts for pinning, paging and the like. Copy the script from the script section: This is an ON OUTCHAT Script. It has to be placed in your Palace Clients "cyborg.ipt" file in the ON OUTCHAT section. Use Notepad, or plain text editors Like Ultraedit or BBedit for this. Wordprocessors will damage scripts. For more information on editing your Cybrog.ipt, please check the Palace Planet HELP section. (don't forget to RELOAD scripts from the file menu of your client) USAGE: `g Gags one selected person. `ug UNgags one selected person. `pg Propgags one selected person. `upg UNPropgags one selected person. `pn Pins one selected person. `upn UNpins one selected person. `k Kills one selected person. `uu Unpins, Ungags, and Unpropgags YOU. `l List someone `w Shows online wizards `p Sends a page `ss Show the current selected snert (whisper to set the snert) This feature remebers who the last user you pinned/gagged etc... When `ss is said without being followed by a name or being whispered, it will display your SS.This allows `ug to ungag the person you last gagged and so on

Code :

; *******************************************************************
;                           WIZARD  SCRIPTS 2.2
;
; The following code pieces are placed in your cyborg file
; inside your ON OUTCHAT and ON SIGNON event handlers. 
;
; Author: Wings, aka CodeWarrior  (revamped by Hex)
;
;       `g              Gags one selected person.
;       `ug             UNgags one selected person.
;       `pg             Propgags one selected person.
;       `upg            UNPropgags one selected person.
;       `pn             Pins one selected person.
;       `upn            UNpins one selected person.
;       `k              Kills one selected person.
;       `uu             Unpins, Ungags, and Unpropgags YOU.
;       `l              List someone
;       `w              Shows online wizards
;       `p <msg>        Sends a page
;       `ss             Show the current selected snert (whisper to set the snert)
;                        This feature remebers who the last user you
;                        pinned/gagged etc... When `ss is said without being followed by a name
;                        or being whispered, it will display your SS.
;                        This allows `ug to ungag the person you last gagged and so on
;--- On Signon Section Begin ---
	wtGet GLOBAL
	{	com =
		{ "$1" GREPSUB wt = } "$1" GREPSUB "" == NOT "$1" GREPSUB "$1" == NOT AND IF
		{ WHOTARGET wt = } WHOTARGET IF
		{	{ com " " & wt & SAY } wt VARTYPE SWAP POP 4 == IF
			{ com wt PRIVATEMSG } wt VARTYPE SWAP POP 1 == IF
		} {	{ com " " & wt & SAY }
			{ com wt PRIVATEMSG } wt "~" > IFELSE
		} IPTVERSION IFELSE
	} wtGet DEF
;--- On Signon Section End ---
;--- On Outchat Section Begin ---
	wt GLOBAL
	wtGet GLOBAL
	{ "`page $1" GREPSUB CHATSTR = } CHATSTR "^`p (.*)" GREPSTR IF
	{ "`opcount" SAY "`glist -w -o" SAY "" CHATSTR = } CHATSTR "`w" == IF
	{ "$1" GREPSUB wt PRIVATEMSG "" CHATSTR = } CHATSTR "^`ws (.*)" GREPSTR IF
	{	{ "$1" GREPSUB wt = } "$1" GREPSUB "" == NOT "$1" GREPSUB "$1" == NOT AND IF
		{ WHOTARGET wt = } WHOTARGET IF
		"Snert Set: " wt { ITOA } wt VARTYPE SWAP POP 1 == IF & LOCALMSG
		"" CHATSTR =
	} CHATSTR "`ss" == CHATSTR "^`ss (.*)" GREPSTR OR IF
	{	"`list -o -p" wtGet EXEC "`list -k" wtGet EXEC
		"" CHATSTR =
	} CHATSTR "^`l (.*)" GREPSTR CHATSTR "`l" == OR IF
	{	"`gag" wtGet EXEC "`list" wtGet EXEC
		"" CHATSTR =
	} CHATSTR "^`g (.*)" GREPSTR CHATSTR "`g" == OR IF
	{	"`ungag" wtGet EXEC
		"" CHATSTR =
	} CHATSTR "^ug (.*)" GREPSTR CHATSTR "`ug" == OR IF
	{	"`pin" wtGet EXEC "`list -o" wtGet EXEC
		"" CHATSTR =
	} CHATSTR "^`pn (.*)" GREPSTR CHATSTR "`pn" == OR IF
	{	"`unpin" wtGet EXEC
		"" CHATSTR =
	} CHATSTR "^upn (.*)" GREPSTR CHATSTR "`upn" == OR IF
	{	"`propgag" wtGet EXEC "`list -o" wtGet EXEC
		"" CHATSTR =
	} CHATSTR "^`pg (.*)" GREPSTR CHATSTR "`pg" == OR IF
	{	"`unpropgag" wtGet EXEC
		"" CHATSTR =
	} CHATSTR "^upg (.*)" GREPSTR CHATSTR "`upg" == OR IF
	{	"$1" GREPSUB tm = "$2" GREPSUB nm =
		{	"`list -o -p" wtGet EXEC " `list -k" wtGet EXEC
			"`trackfor 20" wtGet EXEC
			"`killfor " tm & wtGet EXEC
		} nm "(.*)" GREPSTR IF
		"" CHATSTR =
	} CHATSTR "^`k ([0-9]+) (.*)" GREPSTR IF
	{	"$1" GREPSUB tm = "$2" GREPSUB nm =
		nm "(.*)" GREPSTR POP
		"`list -o -p" wtGet EXEC " `list -k" wtGet EXEC
		"`trackfor 20" wtGet EXEC
		"`killfor " tm & wtGet EXEC
		"" CHATSTR =
	} CHATSTR "^`k ([0-9]+)" GREPSTR IF
	{	"`list -o -p" wtGet EXEC " `list -k" wtGet EXEC
		"`trackfor 20" wtGet EXEC
		"`kill" wtGet EXEC
		"" CHATSTR =
	} CHATSTR "^`k (.*)" GREPSTR CHATSTR "`k" == OR IF
	{	{ "`unpin " USERNAME & SAY } POSX 490 == POSY 362 == AND IF
		  "`ungag " USERNAME & SAY
		{ "`unpropgag " USERNAME & SAY } NBRUSERPROPS NOT IF
		"" CHATSTR =
	} CHATSTR "`uu" == IF

Submited by : hex

Posted on : 2002-07-14

Add your Script
Tell a friend