im looking for a transparent animated snow script .. can anyone help..ty

What you need is a basic animation script and transparent snow pictures. Animation script from the scriptbarn is very usefull.

http://www.palaceplanet.net/scriptbarn/ But will have to try and dig up snow pics, if I find them i'll post them.

I know this time of year the snow script might be of some use. so i provide the script for snow/rain and the images for snow. if someone makes the rain images please let me know.

palace://palacemegadome.com:9998/
To Download The Snow Images

at Palace Mega Dome i have the 3 images 1 2 3 repeated 5 times in that order (1 2 3) to make a total of 15 images.

Snow/Rain Script Below.


;Alan's Rain/snow script
;Create a rain or snow picture that is taller than the room.
;Put the picture in the spot multiple (e.g., 10) times.
;Customize the information between the lines of asterisks.
;Then say "setpictures <door number>" to automatically set the picture locations.
;Note, you must be an owner/operator to do this.
;Other useful commands provided are:
;Say "reset <doornumber>" to set the spot to the first picture.
;Say "mp" to find the current mouse position.
ON ENTER
{
nbrpics GLOBAL
;***Set the number of pictures***
15 nbrpics =
;***end of data***
0 ME SETSPOTSTATELOCAL
0 ME SETALARM
}
ON OUTCHAT
{
nbrpics GLOBAL
{
{
;*************************************************
;Set the picture parameters.
;Start and stop positions are relative to the door.
;You must be an Owner/Operator for the script to work.
0 start_x =
-50 start_y =
0 stop_x =
0 stop_y =
;*************************************************
nbrpics 1 - steps =
stop_x start_x - range_x =
stop_y start_y - range_y =
;
;Move the pictures. Multiply before divide to reduce error!
;
0 i =
{ i ME SETSPOTSTATE
start_x range_x i * steps / + start_y range_y i * steps / + ME SETPICLOC
i ++
} { i nbrpics 1 - <= } WHILE
0 ME SETSPOTSTATE
0 inout =
"" CHATSTR =
} "$1" GREPSUB ATOI ME == IF
} CHATSTR "^setpictures ([0-9]+)" GREPSTR IF
;
{
{ 0 ME SETSPOTSTATE
0 inout =
"" CHATSTR =
} "$1" GREPSUB ATOI ME == IF
} CHATSTR "^reset ([0-9]+)" GREPSTR IF
;
{ MOUSEPOS y = x =
"@" x ITOA & " " & y ITOA & " x = " & x ITOA & ", y = " & y ITOA & LOCALMSG
"" CHATSTR =
} CHATSTR "mp" == IF
}
ON ALARM
{
nbrpics GLOBAL
ME GETSPOTSTATE 1 + nbrpics % ME SETSPOTSTATELOCAL ;cycle up
30 ME SETALARM
}
;********End Script***********



if any questions simply reply to this post to save others from asking same questions


Hope you enjoy and happy holidays
Clint
aka.
Spyder

;A more simpler way to do it is to use the script below and place the
;pictures in the same door as the script. Download the zip with the snow
;images and upload them to your palace.

;Download snow images:

;Download: http://rphosting.net/downloads/snow.zip

;SCRIPT:


ON ENTER { 1 ME SETALARM }
ON ALARM {
3 pics =
ME GETSPOTSTATE 1 + DUP pics / pics * -
ME SETSPOTSTATELOCAL
25 ME SETALARM
}

the reason for the complexity of the script i supplied is due to its ability to setpicloc so the snow feels more real the simple animation script will work for snow.