;Authoring Tools by Hex - http://hex.palaceplanet.net
;Many of these tools inspired by Glide. (Info idea by Panic!)

	{	"$1" GREPSUB infoMde =
		{ "room spot me all" infoMde = } infoMde "" == IF
		{	"; Error: Unknown Parameter. Try: Room, Spot, Me or All" LOCALMSG "" infoMde =
		} infoMde "room" SUBSTR infoMde "spot" SUBSTR OR infoMde "me" SUBSTR OR infoMde "all" SUBSTR OR NOT IF
		
		{	"; *** Info for Room ***" LOCALMSG
			"; Server: " SERVERNAME &
			"  Room: " & ROOMNAME &
			"  ID: " & ROOMID ITOA & LOCALMSG
			"; There are " NBRDOORS ITOA & " doors, " & NBRSPOTS NBRDOORS - ITOA &
			" spots and " &  NBRROOMUSERS ITOA & " users." & LOCALMSG			
		} infoMde "room" SUBSTR IF
	    
		{	"; *** Info for Me ***" LOCALMSG
			"; Name: " USERNAME &
			"  ID: " & WHOME ITOA &
			"  Rank: " &
			{ "Guest" & } { { { "God" & } { "Wizard" & } ISGOD IFELSE } { "Member" & } ISWIZARD IFELSE } ISGUEST IFELSE
			"  Position: " & POSX ITOA & " " & POSY ITOA & LOCALMSG
			TICKS 216000 / h = TICKS 3600 / h 60 * - m = "; Time since last reboot: "
			{ h ITOA & " hour" & { "s" & } h 1 > IF " and " & } h 0 > IF m ITOA & " minutes." & LOCALMSG 
			"; Current Props: " { pc USERPROP ITOA & " " & pc ++ } { pc NBRUSERPROPS < } WHILE LOCALMSG		
		} infoMde "me" SUBSTR IF
				
		{	"; *** Info for Spots ***" LOCALMSG
			"; There are " NBRDOORS ITOA & " doors and " & NBRSPOTS NBRDOORS - ITOA &
			" spots. " & LOCALMSG
			{	"; ID = " f SPOTIDX ITOA &
				"  State = " & f SPOTIDX GETSPOTSTATE ITOA &
				{ "  Name = \"" & f SPOTIDX SPOTNAME & "\"" & } f SPOTIDX SPOTNAME "" == NOT IF
				{ "  Dest = " & f SPOTIDX SPOTDEST ITOA & } f SPOTIDX SPOTDEST 0 <> IF
				{ "  <Locked>" & } f SPOTIDX ISLOCKED IF
				{ "  <In Spot>" & } f SPOTIDX INSPOT IF
				LOCALMSG f ++
			} { f NBRSPOTS < } WHILE	     
		} infoMde "spot" SUBSTR IF
	    
		{	"; *** Info for All ***" LOCALMSG
			"; There are " NBRROOMUSERS ITOA & " users. (Listed in Entrance Order)" & LOCALMSG
			{	"; Name: " u ROOMUSER WHONAME &
				"  ID: " & u ROOMUSER ITOA & 
				"  Position: " u ROOMUSER WHOPOS SWAP ITOA " " & SWAP ITOA & & & LOCALMSG
				u ++
			} { u NBRROOMUSERS < } WHILE			
		} infoMde "all" SUBSTR IF
		
		"" CHATSTR = 
	} CHATSTR "^info *(.*)" GREPSTR IF
	
{ ";My mouse position: " MOUSEPOS SWAP ITOA " " & SWAP ITOA & & LOCALMSG "" CHATSTR = } CHATSTR "mopos" == IF
{ ";My current position: " POSX ITOA & " " & POSY ITOA & LOCALMSG "" CHATSTR = } CHATSTR "mepos" == IF