ROOM
	ID 283
	NAME "**Dart Game by garry\A9"
	PICT "dart_garry.gif"
	PICTURE ID 1 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	DOOR
		ID 1
		DONTMOVEHERE
		OUTLINE 79,35  205,35  205,162  79,162
		LOC 142,98
		SCRIPT
ON SELECT {
rn global scrd global
{ mousepos y = x = x 10 - 20 random + px = y 53 - 20 random + py =
-1283162992 px py addlooseprop
px 142 - relx = py 55 - rely =
relx relx * rely rely * + squareroot r =
1 fak = " " val =
{ "out" val = 0 sc = 1 ne = } r 41 > IF
{ "double" val = 2 fak = } r 41 <= r 39 >= and IF
{ "tripple" val = 3 fak = } r 24 <= r 22 >= and IF
{ "bulls eye" val = 25 sc = 1 ne = } r 5 <= r 3 >= and IF
{ "bulls eye" val = 50 sc = 1 ne = } r 3 < IF
{ 10 betx = { 1000 betx = relx -1 * relx = } relx 0 < if
1 bety = { 100 bety = rely -1 * rely = } rely 0 < if
rely 1000 * r / sin =  relx 1000 * r / cos =
{ 1 snr = } sin 90 SINE <= IF
{ 2 snr = } sin 72 SINE <= IF
{ 3 snr = } sin 54 SINE <= IF
{ 4 snr = } sin 36 SINE <= IF
{ 5 snr = } sin 18 SINE <= IF
{ 1 cnr = } cos 0 COSINE <= IF
{ 2 cnr = } cos 18 COSINE <= IF
{ 3 cnr = } cos 36 COSINE <= IF
{ 4 cnr = } cos 54 COSINE <= IF
{ 5 cnr = } cos 72 COSINE <= IF
snr bety * cnr betx * + code =
{ 20 sc = } code 150 == code 140 == or IF
{ 1 sc = } code 240 == code 250 == or code 230 == or IF
{ 18 sc = } code 330 == code 320 == or code 340 == or IF
{ 4 sc = } code 420 == code 410 == or code 430 == or IF
{ 13 sc = } code 510 == code 520 == or IF
{ 6 sc = } code 15 == code 14 == or IF
{ 10 sc = } code 24 == code 23 == or code 25 == or IF
{ 15 sc = } code 33 == code 32 == or code 34 == or IF
{ 2 sc = } code 42 == code 41 == or code 43 == or IF
{ 17 sc = } code 51 == code 52 == or IF
{ 3 sc = } code 5001 == code 5002 == or IF
{ 19 sc = } code 4002 == code 4001 == or code 4003 == or IF
{ 7 sc = } code 3003 == code 3002 == or code 3004 == or IF
{ 16 sc = } code 2004 == code 2003 == or code 2005 == or IF
{ 8 sc = } code 1005 == code 1004 == or IF
{ 11 sc = } code 1500 == code 1400 == or IF
{ 14 sc = } code 2400 == code 2300 == or code 2500 == or IF
{ 9 sc = } code 3300 == code 3200 == or code 3400 == or IF
{ 12 sc = } code 4200 == code 4100 == or code 4300 == or IF
{ 5 sc = } code 5100 == code 5200 == or IF } ne not if
val " " & sc itoa & say
sc fak * scrd + scrd =  rn ++
{ calc GLOBAL calc EXEC } rn 3 == IF } rn 3 < IF
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 4
		DONTMOVEHERE
		OUTLINE 397,4  458,4  458,27  397,27
		LOC 427,15
		SCRIPT
ON SELECT {
score global 301 score =
clearlooseprops
"My score is " score itoa & SAY
rn global 0 rn = scrd global 0 scrd =
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 5
		DONTMOVEHERE
		OUTLINE 308,5  375,5  375,28  308,28
		LOC 341,16
		SCRIPT
ON SELECT {
"Look in your Logwindow for rules!" localmsg
"Darts rules (301):
Each player starts with 301 points, the first one to reduce his/her score exactly down to 0 wins the game.
Each player takes turns throwing 3 darts each, subtracting all points from their score.
Outside ring counts Double points, inner ring Triple points.
Center ring is worth 25 points and bullseye 50 (Double 25)." logmsg
"Each player must start with a Double (outside ring or bullseye).
To <go out> you must hit a Double and it must make your score exactly 0.
*For a shorter game you may start straight, without a Double.*" logmsg
"How to play DART on palace:
Click 3 times on dartboard and you will see your points. after 3rd shut, new score is indicated.
Try to get exactly 0 points.
Reset will set back the score to 301 for a new game." logmsg
"If you throw too quick, say 'oops' to reset the round but not the score" logmsg
"Enjoy it!" logmsg
}
		ENDSCRIPT
		ENDDOOR
	SPOT
		ID 6
		NAME "enterscript"
		OUTLINE 256,3  277,3  277,23  256,23
		LOC 266,13
		SCRIPT
ON ENTER {
score global 301 score =
scrd global rn global calc global
{ score global scrd global rn global
{ "too much" say 0 scrd = } scrd score > IF
"Round is " scrd itoa & roommsg
score scrd - score =
"My new score is " score itoa & ". Next player!" & say
{ "!I made it!" say } score NOT IF
0 rn = 0 scrd =
clearlooseprops
} calc DEF
{ "This game works only for new 3.5 client with ipt v1" localmsg } IPTVERSION NOT IF
}
ON OUTCHAT {
{ rn global 0 rn = scrd global 0 scrd =
clearlooseprops
"round reset" roommsg } chatstr "oops" == IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 7
		DONTMOVEHERE
		DEST 341
		OUTLINE 4,354  62,354  62,380  4,380
		LOC 33,366
		PICTS 1,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 8
		DONTMOVEHERE
		DEST 292
		OUTLINE 448,354  508,354  508,379  448,379
		LOC 480,368
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM