ROOM
	ID 214
	NAME "Aerial View"
	PICT "pal45.gif"
	ARTIST "Jade"
	PICTURE ID 1 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		NAME "|  Take Off  |  Right  |  Left  |  Up  |  Down  |  Up Right  |  Up Left  | Down Right  |  Down Left  | Land  |"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 7,361  489,363  489,380  7,380
		LOC 249,362
		SCRIPT
;Scripted Mostly by Frodo, based on a script by Foxy with help from Tandika* and a few stiff kicks from Jade. Art by Jade.
ON SELECT { MOUSEPOS POP y =
{ y < btn += }
[ 72 110 143 169 212 267 315 382 448 483 ] FOREACH
[ { prps GLOBAL
0 i =
[ 0 0 0 0 0 0 0 0 0 ] prps =
{ i USERPROP prps i PUT i ++ } { NBRUSERPROPS i > } WHILE
NAKED
[ 977455508 ] SETPROPS }
{ [ 977455508 ] SETPROPS
0 i = { POSX 10 + POSY SETPOS i ++ } { i 5 < } WHILE }
{ [ 977455584 ] SETPROPS
0 i = { POSX 10 - POSY SETPOS i ++ } { i 5 < } WHILE}
{ [ 977455632 ] SETPROPS
0 i = { POSX  POSY 10 - SETPOS i ++ } { i 5 < } WHILE }
{ [ 977455683 ] SETPROPS
0 i = { POSX  POSY 10 + SETPOS i ++ } { i 5 < } WHILE}
{ [ 977455731 ] SETPROPS
0 i = { POSX 10 + POSY 10 - SETPOS i ++ } { i 5 < } WHILE }
{ [ 977455783 ] SETPROPS
0 i = { POSX 10 - POSY 10 - SETPOS i ++ } { i 5 < } WHILE }
{ [ 977455900 ] SETPROPS
0 i = { POSX 10 + POSY 10 + SETPOS i ++ } { i 5 < } WHILE }
{ [ 977455955 ] SETPROPS
0 i = { POSX 10 - POSY 10 + SETPOS i ++ } { i 5 < } WHILE }
{ prps GLOBAL
NAKED
{ this =
{ this DONPROP } 0 this != IF
} prps FOREACH
}
] btn GET EXEC
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 2
		DONTMOVEHERE
		DEST 301
		OUTLINE 3,4  60,4  60,26  3,26
		LOC 31,15
		PICTS 1,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 3
		DONTMOVEHERE
		DEST 147
		OUTLINE 449,4  508,4  508,24  449,24
		LOC 482,14
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM