ROOM
	ID 209
	NAME "Prop Generator 2"
	PICT "Oracle.gif"
	ARTIST "script by Foxy, pic by Aniela "
	PICTURE ID 1 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	DOOR
		ID 1
		NAME "Forward"
		DONTMOVEHERE
		OUTLINE 256,88  305,88  305,115  256,115
		LOC 275,97
		SCRIPT
;this part is the first button, necessary to the whole thing
;when you add avs, you have to leave and re-enter to see them
ON ENTER { prar GLOBAL cpr GLOBAL -1 cpr =
{  [
[ 923841993 923841997 923842001 924322262 923842025 923842038 923842050 923842059 949272941  ]  ; black vixen
[ 958703651 958703668 958703674 ]
[ 958958815 ]
[ 958958805 ]
[ 958958773 ]
[ 958958837 ]
[ 957247021 ]
;add avatar lines here
] } prar DEF }
ON SELECT{
cpr GLOBAL
prar GLOBAL
prar EXEC proparray =
cpr ++
{ 0 cpr = } cpr proparray LENGTH == IF
proparray cpr GET SETPROPS
"Avatar " cpr 1 + ITOA + "/" + proparray LENGTH ITOA + LOGMSG
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 2
		NAME "Back"
		DONTMOVEHERE
		OUTLINE 168,90  222,90  222,117  168,117
		LOC 199,97
		SCRIPT
;if you want a one button generator, put the outchat handler
;in the forward button
ON OUTCHAT {
	{ "$1" GREPSUB avname =
	"[  " 0 tbl =
	 {tbl USERPROP ITOA + " " + tbl ++
	 } {tbl NBRUSERPROPS == NOT} WHILE
	 " ]  \;" + avname + CHATSTR =
	} CHATSTR LOWERCASE "^setwear (.*)$" GREPSTR IF
;say "setwear <description>"  to say the line of data needed  in
;the forward button for the av you're wearing.
}
ON SELECT{
cpr GLOBAL
prar GLOBAL
prar EXEC proparray =
cpr --
{ proparray LENGTH 1 - cpr = } cpr -1 <= IF
proparray cpr GET SETPROPS
"Avatar " cpr 1 + ITOA + "/" + proparray LENGTH ITOA + LOGMSG
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 3
		NAME "Reset"
		DONTMOVEHERE
		OUTLINE 225,91  253,91  253,115  225,115
		LOC 239,97
		SCRIPT
ON SELECT { cpr GLOBAL prar GLOBAL
prar EXEC proparray =
0 cpr =
proparray cpr GET SETPROPS
"Avatar 1/" proparray LENGTH ITOA + LOGMSG
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 4
		NAME "Random"
		DONTMOVEHERE
		OUTLINE 225,119  253,119  253,143  225,143
		LOC 241,125
		SCRIPT
ON SELECT{
prar GLOBAL
prar EXEC proparray =
proparray LENGTH RANDOM npr =
{ proparray LENGTH 1 - cpr = } cpr -1 == IF
proparray npr GET SETPROPS
"Avatar " npr 1 + ITOA + "/" + proparray LENGTH ITOA + LOGMSG
}
		ENDSCRIPT
		ENDDOOR
	SPOT
		ID 5
		NAME "Single room refresh"
		OUTLINE 322,96  338,96  338,111  322,111
		LOC 367,136
		SCRIPT
;put this in your room and say "refresh" to refresh all the avs in it
;not needed if you have multiple rooms with this generator and
;you decide to use the multiple room option instead
ON OUTCHAT { crp GLOBAL
{  0 crp = 1 ME SETALARM
"Refreshing " ROOMNAME + LOGMSG
"" CHATSTR =
} CHATSTR "refresh" == ISWIZARD AND IF
}
ON ALARM { prar GLOBAL crp GLOBAL
prar EXEC proparray =
proparray crp GET SETPROPS
crp ++ crp ITOA "/" proparray LENGTH ITOA + + LOGMSG
{ 90 ME SETALARM } crp proparray LENGTH < IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 6
		NAME "Multiple room refresh"
		OUTLINE 142,97  158,97  158,109  142,111
		LOC 270,193
		SCRIPT
;this part should go in all of the prop rooms that use this generator
;if you want a multiple room refresh
ON ENTER { crrp GLOBAL crp GLOBAL
{  0 crp = 1 ME SETALARM
"Refreshing " ROOMNAME + LOGMSG
} crrp ISWIZARD AND IF
}
ON ALARM { prar GLOBAL crp GLOBAL rrp GLOBAL crrp GLOBAL
prar EXEC proparray =
proparray crp GET SETPROPS
crp ++ crp ITOA "/" proparray LENGTH ITOA + + LOGMSG
{ 90 ME SETALARM }
{ crrp ++ { 0 crrp = } crrp rrp EXEC LENGTH == IF
rrp EXEC crrp GET GOTOROOM
}  crp proparray LENGTH < IFELSE
}
;this part goes in the first room of your multiple rooms for the refresh
ON OUTCHAT { rrp GLOBAL crp GLOBAL crrp GLOBAL
{ { [ 129 134 ] ;room ids to refresh, in order
} rrp DEF 0 crp = "" CHATSTR =
0 crrp = "Refreshing " ROOMNAME + LOGMSG 1 ME SETALARM
} CHATSTR "Refresh all" == ISWIZARD AND IF
}
;say 'refresh all' to automatically go through all of the rooms in your array
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 7
		DONTMOVEHERE
		DEST 262
		OUTLINE 450,4  505,4  505,24  450,24
		LOC 479,14
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER {
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 8
		DONTMOVEHERE
		DEST 94
		OUTLINE 7,6  63,6  63,28  7,28
		LOC 33,17
		PICTS 1,0,0 ENDPICTS
		ENDDOOR
	ENDROOM