ROOM
	ID 175
	NOPAINTING
	NOCYBORGS
	NAME "Beach Talk Script"
	PICT "blpal42.gif"
	PICTURE ID 1 NAME "arrowrr.gif" TRANSCOLOR 56 ENDPICTURE
	PICTURE ID 2 NAME "arrowll.gif" TRANSCOLOR 56 ENDPICTURE
	SPOT
		ID 1
		OUTLINE 7,5  30,5  30,25  7,25
		LOC 58,29
		SCRIPT
ON ENTER {
"Dude!  Gotta say 'surfs up' to start the fun and 'surfs down' to end the party!" LOCALMSG
surf GLOBAL
1 surf =
}
ON OUTCHAT {
surf GLOBAL
{ 1 surf = "Surf Enabled" LOCALMSG } CHATSTR "surf'*s up" GREPSTR IF
{  0 surf = "Surf Disabled" LOCALMSG } CHATSTR "surf'*s down" GREPSTR IF
{
{
{
[ "Awesome!"
"Cool!"
"Gnarly!"
"Bitchin!"
"Radical!"
"Totally!"
"Rad!"
"Tubular!"
] 8 RANDOM GET CHATSTR =
}
{
"!" PUNCT =
{"$1" GREPSUB CHATSTR = "$2" GREPSUB PUNCT = }
CHATSTR "^(.*)([!.?])$" GREPSTR IF
CHATSTR LOWERCASE CHATSTR =
"Like, " CHATSTR +
[ ", dude" ", bro" ", guy"] 3 RANDOM GET +
PUNCT +
CHATSTR =
} 8 RANDOM 0 == IFELSE
} CHATSTR " " SUBSTR CHATSTR "^[:!^@]" GREPSTR NOT AND IF
} surf IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 3
		DONTMOVEHERE
		DEST 324
		OUTLINE 447,356  508,356  508,381  447,381
		LOC 479,370
		PICTS 1,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 2
		DONTMOVEHERE
		DEST 144
		OUTLINE 5,351  61,351  61,380  5,380
		LOC 33,366
		PICTS 2,0,0 ENDPICTS
		ENDDOOR
	ENDROOM