ROOM
	ID 120
	NAME "Bed Jumping!"
	PICT "pal44.gif"
	PICTURE ID 3 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 4 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		NAME "BasicScripts"
		OUTLINE 1,48  20,48  20,67  1,67
		LOC 124,135
		SCRIPT
; This script was written by Tandika Star
; tired = How much user has jumped
; toomuch = value below server's flood level.
; The above variables are used to keep the player from flooding the server and dying.
; change the value of toomuch below to at least 62 below the flood limit on the server.
ON ENTER { tired GLOBAL 0 tired =
NAKED
"You can jump on the bed by standing in the middle of it and saying \x22jump\x22." LOCALMSG
"...But don't let Mom catch you!" LOCALMSG
}
ON OUTCHAT { tired GLOBAL toomuch GLOBAL 100 toomuch =
{ {	; figure out how much to jump.
{ 0 i = 26 RANDOM 5 + height = 2 RANDOM 2 RANDOM - s2s =
{ POSX s2s + POSY 5 - SETPOS i ++ } { height i > } WHILE ; go up
0 i =
{ POSX s2s + POSY 5 + SETPOS i ++ } { height i > } WHILE ; go down
; increase tiredness
height 2 * tired + tired =
{ ; This handles falling off the bed. If you use a different picture,
; then you will have to reset the "edges" of where jumping is allowed.
0 2 SETSPOTSTATELOCAL 0 tired =
POSX 342 SETPOS
"!WAAAAAaaaaa!" SAY "!I fell off!" SAY
} POSX 186 < POSX 366 > OR IF  ; Reset the edges here!
}
{ "@" POSX ITOA + "," + POSY ITOA + "!You can't! You're not in the middle of the bed!" + LOCALMSG
} 1 2 GETSPOTSTATE == IFELSE
}
{ 0 tired =		; Makes user rest so they don't flood the server
"@" POSX ITOA + "," + POSY ITOA + "!You're tired out from too much jumping!" + LOCALMSG
"@" POSX ITOA + "," + POSY ITOA + "!Catch your breath first!" + LOCALMSG
} tired toomuch < IFELSE
"" CHATSTR =
} CHATSTR "jump" == IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		NAME "JumpingArea"
		OUTLINE 158,253  185,224  324,225  348,252
		LOC 103,142
		SCRIPT
ON SELECT {
1 2 SETSPOTSTATELOCAL
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 3
		DONTMOVEHERE
		DEST 179
		OUTLINE 452,4  508,4  508,25  452,25
		LOC 481,15
		PICTS 4,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 4
		DONTMOVEHERE
		DEST 147
		OUTLINE 5,4  57,4  57,25  5,25
		LOC 31,15
		PICTS 3,0,0 ENDPICTS
		ENDDOOR
	ENDROOM