ROOM
	ID 102
	NAME "Fire Breathing Dragon"
	PICT "pdragon.gif"
	ARTIST "Pepe"
	PICTURE ID 1 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		OUTLINE 4,324  506,333  506,381  4,380
		LOC 254,353
		SCRIPT
ON ENTER { safety GLOBAL 0 safety = }
ON OUTCHAT { { 20 ME SETALARM } CHATSTR LOWERCASE "^(.*)dragon(.*)$" GREPSTR IF }
ON SELECT { safety GLOBAL { 1 safety ++ 20 ME SETALARM }
{ "Giving you a timeout so you won't flood" LOGMSG
{ safety GLOBAL 0 safety = "Is ok now :-)" LOGMSG } 1000 ALARMEXEC } 5 safety > IFELSE }
ON ALARM {
216 cy =
277 cx =
0 i =
1 fdel =
20 nfr =
POSX mx =
POSY my =
{
mx cx - 8 / cx + newx =
my cy - 8 / cy + newy =
"-1339052469 " newx ITOA & " " & newy ITOA & " ADDLOOSEPROP" & STRTOATOM EXEC
newx cx =
newy cy =
i ++
} { i nfr < } WHILE
{ ")boom" SAY [ -1339053018 -1339052982 -1339052977 ]
SETPROPS CLEARLOOSEPROPS } 80 ALARMEXEC
{  [ "@287 243 Flamed !!" "@287 243 Back off Flame head" "@287 243 Toasted !"
"@287 243 Ain't I bad ?" "@287 243 Back off Bubs !" "@287 243 Crispy Critter ahhhhhh" ]
5 RANDOM GET ROOMMSG } 150 ALARMEXEC }
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 2
		DONTMOVEHERE
		DEST 179
		OUTLINE 5,4  68,4  68,26  5,26
		LOC 36,15
		PICTS 1,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 3
		DONTMOVEHERE
		DEST 180
		OUTLINE 447,5  506,5  506,27  447,27
		LOC 477,15
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM